home *** CD-ROM | disk | FTP | other *** search
/ MacWorld 1998 May / Macworld (1998-05).dmg / Updaters / RealPC 1.0.2 Update / RealPC Upgrade Disk / INSIGNIA / DELFILES.BAT < prev    next >
Encoding:
DOS Batch File  |  1998-02-17  |  4.3 KB  |  140 lines
  1. rem [
  2. rem    Name:        u.delfiles.bat
  3. rem
  4. rem    Derived from:    (original)
  5. rem
  6. rem    Author:        Clive Standbridge
  7. rem
  8. rem    Created on:    Dec 1996
  9. rem
  10. rem    Sccs ID:    @(#)u.delfiles.bat    1.13 10/13/97
  11. rem
  12. rem    Coding Stds:    
  13. rem
  14. rem    Purpose:    Hard disk upgrader - delete files.
  15. rem
  16. rem    Parameters:    1    Action required. MUST be one of:
  17. rem                "list"    Delete and/or move files in internal
  18. rem                    list. The batch file processes a list
  19. rem                    of files, calling itself recursively
  20. rem                    to delete or move files as appropriate.
  21. rem                "del"    ONLY TO BE USED RECURSIVELY.
  22. rem                    Delete file(s) in parameter 2.
  23. rem                    Typically this would be used to remove
  24. rem                    obsolete Insignia-supplied files, where
  25. rem                    we are confident that they are obsolete.
  26. rem                "move"    ONLY TO BE USED RECURSIVELY.
  27. rem                    Move file(s) in parameter 2 to directory
  28. rem                    for obsolete files.
  29. rem                    If an obsolete copy already exists, the
  30. rem                    file is simply deleted.
  31. rem                "copy"    ONLY TO BE USED RECURSIVELY.
  32. rem                    Copy file(s) in parameter 2 to directory
  33. rem                    for obsolete files.
  34. rem                    If an obsolete copy already exists, the
  35. rem                    file is not copied.
  36. rem                Typically "move" and "copy" would be used to 
  37. rem                back up obsolete MS or third-party files, where
  38. rem                we wish to exercise some caution in removing
  39. rem                things completely from the user's disk.
  40. rem    Parameters for del action:
  41. rem            2    Full path of file(s) to be deleted/moved.
  42. rem    Parameters for move and copy actions:
  43. rem            2    Path to file to be deleted/moved/copied.
  44. rem            3    Name of file to be deleted/moved/copied.
  45. rem    Parameters for list action:
  46. rem             2       FSA directory for split Windows setup.
  47. rem                             = c:\windows for hard disk only setup.
  48. rem            3       Windows system directory.
  49. rem                             = c:\windows\system for hard disk only setup.
  50. rem            4       Intel OS; must be one of:
  51. rem                "dos", "win311", "wfw311", "win95", "win98".
  52. rem            5       Host OS ("mac", "unix", etc.)
  53. rem
  54. rem    Copyright 1997 Insignia Solutions PLC. All rights reserved.
  55. rem ]
  56.  
  57. goto %1
  58. rem goto end
  59.  
  60. :del
  61. if not exist %2 goto end
  62. echo deleting %2    >>c:\insignia\up.log
  63. del %2            >>c:\insignia\up.log
  64. goto end
  65.  
  66. :move
  67. :copy
  68. if not exist c:\insignia\obsolete\nul mkdir c:\insignia\obsolete    >>c:\insignia\up.log
  69. rem    Move/Copy the file to obsolete directory, unless a copy is already there.
  70. if not exist %2\%3 goto end
  71. if     exist     c:\insignia\obsolete\%3 goto end
  72. echo %1 %2\%3 to c:\insignia\obsolete    >>c:\insignia\up.log
  73. %1 /y   %2\%3    c:\insignia\obsolete    >>c:\insignia\up.log
  74. goto end
  75.  
  76. :list
  77. rem    Process list of files for removal.
  78.  
  79. rem    Obsolete networking setup files
  80. call %0 del  c:\insignia\netisnds.inf
  81. call %0 del  c:\insignia\netisodi.inf
  82. call %0 del  c:\windows\inf\netisnds.inf
  83. call %0 del  c:\windows\inf\netisodi.inf
  84.  
  85. rem    Potentially obsolete utilities may cause trouble;
  86. rem     the upgrader will create new ones when ready.
  87. call %0 del  c:\insignia\inspat95.exe
  88. call %0 del  c:\insignia\insreged.exe
  89.  
  90. rem    Obsolete log files
  91. call %0 del  c:\insignia.out
  92. call %0 del  c:\insignia\out
  93. call %0 del  c:\insignia\patch.out
  94.  
  95. rem    Mis-named batch file
  96. call %0 del  c:\insignia\use_cd.bat
  97.  
  98. rem    Obsolete drivers -  may cause problems
  99. call %0 del  c:\insignia\spcmswd.drv
  100. call %0 del  c:\insignia\swinsnd.drv
  101. call %0 del  %3\spcmswd.drv
  102. call %0 del  %3\swinsnd.drv
  103.  
  104. rem    Obsolete 16-bit stuff and old shortcuts.
  105. itest strnicmp "%4" win9 4
  106. if errorlevel 1 goto not_win95
  107. call %0 del  c:\insignia\smrtcpy.exe
  108. call %0 del  c:\insignia\smrtcp32.exe
  109. call %0 del  c:\insignia\winidle.exe
  110. call %0 del  c:\insignia\wnidle32.exe
  111. call %0 del  %2\smrtcpy.exe
  112. call %0 del  %2\smrtcp32.exe
  113. call %0 del  %2\winidle.exe
  114. call %0 del  %2\wnidle32.exe
  115. call %0 del  c:\insignia\suspend.com
  116. call %0 del  c:\insignia\suspend.pif
  117. call %0 del  c:\windows\suspend.com
  118. call %0 del  c:\windows\pif\suspend.pif
  119.  
  120. call %0 del  %3\vidled.386
  121. rem    Possibly non-Insignia Winsock files
  122. call %0 copy %2 winsock.dll
  123. call %0 copy %3 wsock32.dll
  124. rem    winsock.dll in the SYSTEM directory must result from
  125. rem    installing Windows 95 over Windows 3.1 - just delete it.
  126. call %0 del  %3\winsock.dll
  127. goto all_win
  128.  
  129. :not_win95
  130. rem    Possibly non-Insignia Winsock files
  131. call %0 copy %3 winsock.dll
  132. call %0 copy %3 wsock32.dll
  133. goto all_win
  134.  
  135. :all_win
  136.  
  137. goto end
  138.  
  139. :end
  140.